root/Theme-2/nobu/src/ApplicationThread.as

/**
 *
 *
 **/
package
{
    import flash.display.Bitmap;
    import flash.net.URLRequest;
    import lib.cloud.CloudView;
    import lib.loading.LoadingProgressView;
    import lib.core.PassiveMovieClip;
    import org.libspark.display.LoaderThread;
    import org.libspark.net.URLLoaderThread;
    import org.libspark.thread.Thread;
    //import org.libspark.utils.concurrent.ParallelExecutor;
    import org.libspark.utils.concurrent.SerialExecutor;
    
    /**
     *  全体の動きを制御するクラス
     **/
    internal class ApplicationThread extends Thread
    {
        /**
         *  Applicationのインスタンス
         **/
        private var _view:Application;

        /**
         *  CloudViewのインスタンス
         **/
        private var _cloud:CloudView;

        /**
         *  URLLoaderThreadのインスタンス(XMLロード用)
         */
        private var _xmlLoadThread:URLLoaderThread;

        /**
         *  SerialExecutorのインスタンス(画像ロード用)
         **/
        private var _imageLoadThread:SerialExecutor;
        
        /**
         *  初期化を行う
         *
         *  @param  p_view  Applicationのインスタンス
         **/
        public function ApplicationThread(p_view:Application)
        {
            _view = p_view;
        }

        /**
         *  スレッドの初期化を行う
         **/
        protected override function initialize():void
        {
            //  setup loading progress.
            var l:LoadingProgressView = _view.addChild(new LoadingProgressView({
                name: 'Loading',
                x: _view.stage.stageWidth / 2,
                y: _view.stage.stageHeight / 2
            })) as LoadingProgressView;
            //  show loading.
            l.showThread.begin();
            _xmlLoadThread = new URLLoaderThread(new URLRequest(_view.targetUrl));
            _xmlLoadThread.begin();
            _xmlLoadThread.join();
        }
        
        protected override function execute():void
        {
            switchExecuteMethod(hoge);
            _imageLoadThread = new SerialExecutor();
            var rootNode:XML, location:XML;
            rootNode = new XML(_xmlLoadThread.loader.data);
            for each (location in rootNode.item.location)
            {
                _imageLoadThread.addThread(new LoaderThread(new URLRequest(location.text())));
            }
            _imageLoadThread.begin();
            _imageLoadThread.join();
        }

        private function hoge():void
        {
            switchExecuteMethod(hige);
            //  hide loading.
            LoadingProgressView(_view.getChildByName('Loading')).hideThread.begin();
            var i:int, b:Bitmap, d:Array = [];
            for (i = 0; i < _imageLoadThread.numThreads; i++)
            {
                b = LoaderThread(_imageLoadThread.getThreadAt(i)).loader.content as Bitmap;
                d.push(b);
            }
            _cloud = _view.addChild(new CloudView(d)) as CloudView;
        }

        private function hige():void
        {
            _cloud.actionThread.begin();
        }
        
        protected override function finalize():void
        {
            _view = null;
            _cloud = null;
            trace('finalized.');
        }
    }
}