root/Theme-2/nobu/src/App2Thread.as

/**
 *
 **/
package
{
    import flash.display.Bitmap;
    import flash.net.URLRequest;
    import lib.papervision3d.Papervision3DThread;
    import org.libspark.display.LoaderThread;
    import org.libspark.net.URLLoaderThread;
    import org.libspark.thread.Thread;
    import org.libspark.tweener.TweenerThread;
    import org.libspark.utils.concurrent.SerialExecutor;

    /**
     *  アプリケーション全体を制御するメインスレッド
     **/
    internal class App2Thread extends Thread
    {
        /**
         *  App2のインスタンス
         **/
        private var _view:App2;

        /**
         *  Papervision3Dレンダリング用スレッド
         **/
        private var _pv3dThread:Papervision3DThread;

        /**
         *  XML取得用スレッド
         **/
        private var _xmlLoadThread:URLLoaderThread;

        /**
         *
         **/
        private var _imageLoadThread:SerialExecutor;

        /**
         *  コンストラクタ
         *
         *  @param  p_view  App2のインスタンス
         **/
        public function App2Thread(p_view:App2)
        {
            _view = p_view;
            _pv3dThread = new Papervision3DThread(_view);
        }

        /**
         *  スレッドの初期化を行う
         *
         *  Papervision3Dスレッドの起動
         **/
        protected override function initialize():void
        {
            _pv3dThread.begin();
        }

        /**
         *  XMLの取得
         **/
        protected override function execute():void
        {
            //  次の処理を指定
            switchExecuteMethod(loadImages);
            //  スレッドの生成と起動
            _xmlLoadThread = new URLLoaderThread(new URLRequest(_view.targetUrl));
            _xmlLoadThread.begin();
            //  処理が終わるまで待つ
            _xmlLoadThread.join();
        }

        /**
         *  画像の取得
         */
        private function loadImages():void
        {
            //  次の処理を指定
            switchExecuteMethod(parseImages);
            //  ローディングの切り替え
            new TweenerThread(_pv3dThread.loadingCube, {
                rotationY: 270,
                time: 1.0,
                transition: "easeOutSine"
            }).begin();

            //  XMLのパースと画像の取得
            _imageLoadThread = new SerialExecutor();
            var rootNode:XML, location:XML;
            rootNode = new XML(_xmlLoadThread.loader.data);
            for each (location in rootNode.item.location)
            {
                _imageLoadThread.addThread(new LoaderThread(new URLRequest(location.text())));
            }
            //  スレッドの起動
            _imageLoadThread.begin();
            //  処理が終わるまで待つ
            _imageLoadThread.join();
        }

        /**
         *
         *
         **/
        private function parseImages():void
        {
            switchExecuteMethod(hideLoadingCube);
            var i:int, thread:LoaderThread, data:Array = [];
            for (i = 0; i < _imageLoadThread.numThreads; i++)
            {
                thread = LoaderThread(_imageLoadThread.getThreadAt(i));
                data.push(Bitmap(thread.loader.content));
            }
            _pv3dThread.data = data;
        }

        /**
         *
         *
         **/
        private function hideLoadingCube():void
        {
            //  次の処理を指定
            switchExecuteMethod(forever);
            var hideThread = new SerialExecutor();
            //  ローディングの切り替え
            hideThread.addThread(new TweenerThread(_pv3dThread.loadingCube, {
                rotationY: 360,
                time: 1.0,
                transition: "easeOutSine"
            }));
            hideThread.addThread(new TweenerThread(_pv3dThread.loadingCube, {
                z: -1000,
                time: 1.0,
                transition: "easeOutSine"
            }));
            hideThread.begin();
            hideThread.join();
        }

        /**
         *
         *
         **/
        private function forever():void
        {
            _pv3dThread.start();
        }

        protected override function catchError(thread:Thread, error:Error):void
        {
            trace(error);
            terminate();
        }
    }
}