root/Theme-1/t-matsuda/src/Root.as

/**
 * Theme-1 Root Class for Entacl Develop
 * 
 * DESCRIPTION : ドキュメントクラス
 * 
 * TODO: 
 *
 * @author       t-matsuda <matsuda[at-mark]entacl.com>
 * @version      0.0.1
 *
 * @see          http://www.entacl.com/
 * 
 **/
package {
        import flash.display.MovieClip;
        import flash.display.Sprite;
        import caurina.transitions.Tweener;
        import transition.*;
        import flash.utils.getDefinitionByName;
        import br.com.stimuli.loading.BulkLoader;
        import br.com.stimuli.loading.BulkErrorEvent;
        import br.com.stimuli.loading.BulkProgressEvent;
        import flash.text.TextFieldAutoSize;
        
        public class Root extends MovieClip {
                const XMLFILE:String = '/xml/theme-1/t-matsuda/theme.xml';
                
                private var bulkInstance:BulkLoader;
                private var delay:uint = 3;
                private var tweenTime:uint = 4;
                private var num:int = -1;
                
                public function Root() {
                        init();
                }

                private function init():void {
                        var item:Array = new Array();
                        item.push( { id:'theme-xml', value:XMLFILE, type:'xml' } );
                        
                        setLoader('main', xmlLoaded, item);
                        startLoader();
                }
                
                private function xmlLoaded(event:BulkProgressEvent):void {
                        removeLoading();
                        ThemeXml.getInstance().setXML(bulkInstance.getXML('theme-xml'));
                        
                        nextTheme();
                }
                
                
                private function nextTheme():void {
                        removeTheme();
                        
                        num++;
                        if (ThemeXml.getInstance().getThemeCount() <= num) num = 0; 
                        
                        var mc:MovieClip = new MovieClip();
                        addChild(mc);
                        
                        var theme:ThemeText = new ThemeText();
                        theme.themeInput.autoSize = TextFieldAutoSize.LEFT;
                        theme.themeInput.text = ThemeXml.getInstance().getTheme(num);
                        mc.addChild(theme);
                        
                        var lineMc:MovieClip = new MovieClip();
                        mc.addChild(lineMc);
                        
                        var line1:LineGraphic = new LineGraphic(theme.width, theme.height / 2);
                        lineMc.addChild(line1);
                
                        var line2:LineGraphic = new LineGraphic(theme.width, theme.height / 2);
                        line2.y = theme.height / 2;
                        lineMc.addChild(line2);
                        
                        theme.cacheAsBitmap = true;
                        
                        lineMc.mask = theme;
                        
                        //change transition
                        new PixelDissolveIn(mc, { duration:delay } );
                        
                        Tweener.addTween(theme, {
                                x: -theme.width,
                                delay: delay,
                                time: tweenTime,
                                transition : "linear",
                                onStart: function() {
                                        theme.cacheAsBitmap = false;
                                },
                                onComplete: function () {
                                        nextTheme();
                                }
                        });
                }
                
                private function removeTheme():void {
                        var trash:Array = new Array();
                        for (var i:uint = 0; i < numChildren; i++ ) {
                                trash.push(getChildAt(i));
                        }
                        
                        for each (var item in trash) {
                                removeChild(item);
                        }
                }
                
                
                private function setLoader(name:String, complete:Function, add:Array):void {
                        bulkInstance = new BulkLoader(name);
                        bulkInstance.addEventListener(BulkLoader.ERROR, onError);
                        bulkInstance.addEventListener(BulkLoader.PROGRESS, onProgress);
                        bulkInstance.addEventListener(BulkLoader.COMPLETE, complete);
                        
                        for each (var item:Object in add) {
                                bulkInstance.add(item.value, {id:item.id, type:item.type});
                        }
                }
                
                private function startLoader():void {
                        bulkInstance.start();
                }
                
                private function onError(event:BulkErrorEvent):void {
                        for each (var err:String in event.errors) {
                                trace('error message:' + err);
                        }
                }
                
                private function onProgress(event:BulkProgressEvent):void {
                        setLoading();
                }
                
                private function setLoading():void {
                        var loadingMc:Loading = new Loading();
                        loadingMc.x = stage.stageWidth / 2;
                        loadingMc.y = stage.stageHeight / 2;
                        addChild(loadingMc);
                }
                
                private function removeLoading():void {
                        var trash:Array = new Array();
                        for (var i:int = 0; i < numChildren; i++ ) {
                                if (getChildAt(i) is Loading) {
                                        trash.push(getChildAt(i)); 
                                }
                        }
                        
                        for each (var item:Loading in trash) {
                                removeChild(item);
                        }
                }
        }
        
}