root/Theme-1/nobu/Base.as

package
{
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.events.SecurityErrorEvent;
    import flash.net.URLRequest;
    import flash.net.URLRequestMethod;
    import flash.net.URLLoader;
    import flash.net.URLVariables;
    import lib.display.MovieClipExt;

    public class Base extends MovieClipExt
    {
        private var index:int;
        private var items:Array;

        public function Base()
        {
        }

        override protected function wakeUp(evt:Event):void
        {
            loadRSS();
            super.wakeUp.call(this, evt);
        }

        private function loadRSS():void
        {
            var url:String = loaderInfo.parameters['feed-url'] || '/feed/';
            var req:URLRequest = new URLRequest(url);
            var loader:URLLoader = new URLLoader();
            loader.addEventListener(Event.OPEN, onOpen, false, 0, true);
            loader.addEventListener(Event.COMPLETE, onComplete, false, 0, true);
            loader.addEventListener(IOErrorEvent.IO_ERROR, onError, false, 0, true);
            loader.addEventListener(SecurityErrorEvent.SECURITY_ERROR, onError, false, 0, true);
            loader.load(req);
        }

        private function showRSS(evt:Event=null):void
        {
            if (items.length <= 0) return;
            if (index >= items.length) index = 0;
            var p:Panel = addChild(new Panel(items[index++])) as Panel;
            p.addEventListener(Event.REMOVED_FROM_STAGE, showRSS, false, 0, true);
        }

        private function onOpen(evt:Event):void
        {
            showLoading();
        }

        private function onComplete(evt:Event):void
        {
            var item:XML;
            var category:XML;
            var rss:XML = new XML(evt.target.data);
            index = 0;
            items = [];
            for each (category in rss.channel.item.category)
            {
                if (category.text() == 'Theme')
                {
                    item = category.parent();
                    items.push({
                        title: item.title.text(),
                        link: item.link.text(),
                        pubDate: new Date(Date.parse(item.pubDate.text())),
                        description: item.description.text()
                    });
                }
            }
            removeChild(getChildByName('loading'));
            if (items.length > 0)
            {
                showRSS();
            }
        }

        private function onError(evt:Event):void
        {
            hideLoading();
            showFailure();
        }

        private function showLoading():void
        {
            var l:Loading = getChildByName('loading') as Loading;
            if (!(l is Loading))
            {
                l = addChild(new Loading()) as Loading;
                l.name = 'loading';
            }
            l.visible = true;
        }

        private function hideLoading():void
        {
            var l:Loading = getChildByName('loading') as Loading;
            if (l is Loading)
            {
                l.visible = false;
            }
        }

        private function showFailure():void
        {
            var f:Failure = getChildByName('failure') as Failure;
            if (!(f is Failure))
            {
                f = addChild(new Failure()) as Failure;
                f.name = 'failure';
            }
            f.visible = true;
        }

        private function hideFailure():void
        {
            var f:Failure = getChildByName('failure') as Failure;
            if (f is Failure)
            {
                f.visible = false;
            }
        }
    }
}